Использование Ms Agent в проектах Delphi.

---

При создании этого материала были использованы Microsoft Agent Control 2.0 (Version 2.0) и Персонаж Merlin. Необходимые компоненты можно загрузить сдесь.

• Установка.
• Экспорт в Delphi.
• Об Ms Agent.
• Использование в своем приложении.
• Использование в HTML
• Персонажи.

Установка.

Установка Ms Agent не должна вызвать проблем. Распакуйте архив и запустите файл msagent.exe на выполнение. Далее следуйте инструкциям указаным при установке. Аналогичным образом действуйте при установке персонажа "Мерлин" из файла merlin.exe.

Экспорт в Delphi.

1. В меню Component выберите Install ActiveX control ...
2. В появившемся диалоговом окне, в списке, найдите Microsoft Agent Control 2.0 (Version 2.0). Если в списке такой строки нет, то нажмите кнопку Add и наидите файл Agentctl.dll.
3. Выберете строку Microsoft Agent Control 2.0 (Version 2.0). В поле Class names должно появится слово TAgent, и загорется кнопка Install...
4. Нажмите кнопку Install...

Об Ms Agent.

• IAgentCtlCharacters - Используется для загрузки и выгрузки персонаей. Содержит список всех загруженных персонажей.
• IAgentCtlCharacterEx - Самый основной интерфейс. Через него осуществляются все манипуляции с персонажем.
• IAgentCtlRequest - Хранит в себе состояние персонажа. Часто используется для остановки действий персонажа и синхронизации действий нескольких персонажей между собой.

  Существуют и другие полезные интерфейсы:

• IAgentCtlAnimationNames - осуществляет перебор всех анимаций реализованных в персонаже.
• IAgentCtlBalloonEx - отвечает за область в которую выводится текст, когда персонаж разговаривает.

Использование в своем приложении.

Модуль Main

Теперь разберемся как это все работает. Подготавливаем персонаж к работе. Для этого в обработчике onCreate пишем следуюший код:

procedure TForm1.FormCreate(Sender: TObject);
begin
 Agent1.Characters.Load('Char', 'merlin.acs'); //Загружаем персонаж из файла merlin.acs
 Character := Agent1.Characters.Character('Char') as IAgentCtlCharacterEx;
 //Присваеваем указатель на интерфейс IAgentCtlCharacterEx переменной
 AgentAnimationEnum; //Заполняем список анимаций
 ToolButton3Click(Sender); //Позиционируем персонаж в "Домашней позиции"
 Character.Commands.Add('Test', '&Test', 1, 1, True);
 Character.Commands.Add('Demo', '&Demo', 1, 1, True);// Добавляем в меню две комманды
 Memo1.Lines.Clear;
{ Показать опсиание персонажа }
 Memo1.Lines.Add(Character.Description);
 Memo1.Lines.Add('Version ' + Character.Get_Version);
end;
 

procedure TForm1.AgentAnimationEnum;
var AEnum: IEnumVariant;
    Fetch: Cardinal;
    V: OleVariant;
begin
 AnimationNames := Character.AnimationNames;
 AEnum := AnimationNames.Enum as IEnumVariant;
 // Получаем интерфейс IEnumVariant для перебора анимаций
 AEnum.Reset;
 ListBox1.Items.Clear; // Подготавливаем IEnumVariant к перебору анимаций и список к их хранению
Repeat
 AEnum.Next(1,V,Fetch); //Начинаем перебор анимаций
  If VarToStr(V) <> EmptyStr Then // Пропускаем пустые строки
   ListBox1.Items.Add(V); // Добавляем имя анимации в список
until Fetch=0; //выходим из цикла если перебор закончен

end;

procedure TForm1.ToolButton3Click(Sender: TObject);
var
 PanelPos : TPoint;
 Pos      : TPoint;
 X,Y      : Integer;
begin
 PanelPos.x := Panel1.Left;
 PanelPos.Y := Panel1.Top;
 Pos := ClientToScreen(PanelPos); // Переводим координаты панели в координаты экрана
 // Вычисляем координаты точки перемещения
 X := Pos.X+Panel1.Width DIV 2  - Character.Width DIV 2;
 Y := Pos.y+Panel1.Height DIV 2 - Character.Height DIV 2;
 Character.MoveTo(X,Y,1); // перемещаем Персонаж
end;

procedure TForm1.ListBox1Click(Sender: TObject);
begin
 ListBox1.Hint := ListBox1.Items[Listbox1.ItemIndex];
 Req := Character.Play(WideString(ListBox1.Items[Listbox1.ItemIndex]));
 //Воспоризводим выбранную анимацию
end;

procedure TForm1.Agent1Click(Sender: TObject;
  const CharacterID: WideString; Button, Shift, x, y: Smallint);
begin
try
 Character.Stop(Req); // Останавливаем действие которое содержится в переменной Req
finally
 Req := Character.Play('RestPose'); // При любом исходе возвращаем персонаж в исходное состояние
end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var X,Y: Integer;
begin
try
 X := StrToInt(Edit1.Text);
 Y := StrToInt(Edit2.Text); // Преобразуем введенные координаты из стороки в число
 Character.MoveTo(X,Y,1); // перемещаем персонаж
except
 Toolbutton1click(nil); // При возникновении ошибки перемещаемся в "домашнее положение"
end;
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
 Character.Play('Think'); // Проиграть анимацию задумчивости
 Character.Think('И что от меня хотят?'); // Произнести фразу
end;

procedure TForm1.Agent1Command(Sender: TObject;
  const UserInput: IDispatch);
var
 Cmd : IAgentCtlUserInput;
begin
 Cmd := UserInput as IAgentCtlUserInput;
 If Cmd.Name = 'Test' Then // Если выбрана комманда "Test"
 // Соответствующие действия
 begin
  Character.Speak('Вызвали команду Test','');
  req := Character.Play('Processing');
 end;
 If Cmd.Name = 'Demo' Then // Если выбрана комманда "Demo"
// Соответствующие действия
 begin
  Character.Speak('Вызвали команду Demo','');
  req := Character.Play('DoMagic1');
  req := Character.Play('DoMagic2');
  Req := Character.Play('RestPose');
 end;
end;

Использование в HTML

Персонажи.

Download

Microsoft Agent Control 2.0 (Version 2.0)

Персонаж "Merlin"

Microsoft Agent Character Editor